(ATCScript "FlowDurationGraphTimeseries Script"
  (Arg "DataFileObject")
  (Arg "Locations")
  (Arg "Scenarios")
  (Arg "GraphTitle")
  (Arg "SDate")
  (Arg "Edate")

  (For CurLocation in Locations
    (Graph TIME SDate Edate)
    (Graph Grid 1 1 0)

    (Graph TITLE (+ "Daily Mean Flow at " Curlocation "&"
                 (JDatediff SDate EDate "yr") " Year " gSimType)
                 Caption
    )

    (Set curMaxAxisVal 0)
    (For CurScenario in Scenarios
      (Set DataSet (DataFile DataFileObject Data Location CurLocation 
                                                 Scenario CurScenario
                                                 Constituent "Flow"))
      (Set DataSet (DataTSer DataSet SubSetByDate SDate EDate))
      (Graph DATA DataSet)
      (Graph AGGR 4 1 0)

      (If (> (DataTSer DataSet Attrib "MAX") curMaxAxisVal)
        (Set curMaxAxisVal (DataTSer DataSet Attrib "MAX"))
      )

      (If (= CurScenario "Observed")
        (Set Color "Blue")
        (Set LineType 1)
        (Set LegendCaption "Observed")
        (Else
          (Set Color "Red")
          (Set LineType 3)
          (Set LegendCaption (+ "Simulated (" (Format (FileAttribute (DataFile DataFileObject FileName) "date") "yyyy-mm-dd hh:mm") ")"))
        )
      )

      (Graph CURVE 6 LineType 1 0 Color LegendCaption)
    )

    (C establish maximum y-axis value)
    (Set curMaxAxisVal (RunScript (+ StandardsDir "MaxAxisVal.spt") curMaxAxisVal))

    (Graph SCALE 1 (* 5 curMaxAxisVal) 10 0 0 0 0 0 0 -3.0 3.0 0 0 0 0 0)
    (Graph AXIS 1 1 0 0 "Percent chance FLOW exceeded" "Discharge (cfs)" "YR" "Precip(in)")
    (Graph SHOW DUR)
    (Set curFile (+ OutputDir CurLocation GraphTitle ".png"))
    (Graph SAVE curFile)
    (Graph CLEAR)

    ('If (= PrintFile "print")
      (OpenFile curFile PrintFile)
    )
  )
  (UnSet DataSet)
  (UnSet Color)
  (UnSet LineType)
  (UnSet LegendCaption)
  (UnSet curMaxAxisVal)
)